Автор перевода: Майкл "Antares" Клишин	Предыдущая | Следующая | Оглавление

Mouse.onMouseMove

Доступность

Flash Player 6.

Синтаксис

someListener.onMouseMove

Параметры

Нет.

Возвращает

Ничего.

Описание

Слушатель событий, листенер (Listener); оповещается при движении мыши. Чтобы использовать листенер onMouseMove, необходимо сначала создать объект. Затем вы можете определить ему обработчик onMouseMove и использовать метод addListener(), чтобы зарегистрировать листенер в объекте Mouse, как показано на примере:

var someListener:Object = new Object();
someListener.onMouseMove = function() { ... };
Mouse.addListener(someListener);

Листнеры позволяют различным фрагментам кода работать совместно, потому что оповещение об одном событии могут получить несколько листнеров одновременно.

Пример

В примере ниже курсором рисуются линии, при этом используется обработчик события onMouseMove и функции Drawing API. Линии рисуются при прижатой левой кнопке.

this.createEmptyMovieClip("canvas_mc", this.getNextHighestDepth());
var mouseListener:Object = new Object();
mouseListener.onMouseDown = function() {
  this.isDrawing = true;
  canvas_mc.lineStyle(2, 0xFF0000, 100);
  canvas_mc.moveTo(_xmouse, _ymouse);
};
mouseListener.onMouseMove = function() {
  if (this.isDrawing) {
    canvas_mc.lineTo(_xmouse, _ymouse);
  }
  updateAfterEvent();
};
mouseListener.onMouseUp = function() {
  this.isDrawing = false;
};
Mouse.addListener(mouseListener);

В примере ниже курсор скрывается, а координаты x и y мувиклипа pointer_mc приравниваются координатам x и y курсора. Создайте новый мувиклип и присвойте ему Linkage идентификатор pointer_id. Добавьте следующий код в первый кадр Таймлайна:

// Для тестирования этого кода необходимо,
// чтобы в Библиотеке был символ с Linkage идентификатором "pointer_id".
this.attachMovie("pointer_id", "pointer_mc", this.getNextHighestDepth());
Mouse.hide();
var mouseListener:Object = new Object();
mouseListener.onMouseMove = function() {
  pointer_mc._x = _xmouse;
  pointer_mc._y = _ymouse;
  updateAfterEvent();
};
Mouse.addListener(mouseListener);

См. также

Mouse.addListener()

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление